PBR shader work
This commit is contained in:
parent
8eb2d7140a
commit
62a27191aa
GPG key ID:
016F11E0AA296B67
7 changed files with 252 additions and 0 deletions
|
|
@ -182,12 +182,24 @@
|
|||
<ShaderModel Condition="'$(Configuration)|$(Platform)'=='Debug|x64'">5.0</ShaderModel>
|
||||
<ShaderModel Condition="'$(Configuration)|$(Platform)'=='Release|x64'">5.0</ShaderModel>
|
||||
</FxCompile>
|
||||
<FxCompile Include="SimplePixelPBR.hlsl">
|
||||
<ShaderType Condition="'$(Configuration)|$(Platform)'=='Debug|x64'">Pixel</ShaderType>
|
||||
<ShaderType Condition="'$(Configuration)|$(Platform)'=='Debug|Win32'">Pixel</ShaderType>
|
||||
<ShaderType Condition="'$(Configuration)|$(Platform)'=='Release|Win32'">Pixel</ShaderType>
|
||||
<ShaderType Condition="'$(Configuration)|$(Platform)'=='Release|x64'">Pixel</ShaderType>
|
||||
</FxCompile>
|
||||
<FxCompile Include="SimplePixelShader.hlsl">
|
||||
<ShaderType Condition="'$(Configuration)|$(Platform)'=='Debug|x64'">Pixel</ShaderType>
|
||||
<ShaderType Condition="'$(Configuration)|$(Platform)'=='Debug|Win32'">Pixel</ShaderType>
|
||||
<ShaderType Condition="'$(Configuration)|$(Platform)'=='Release|Win32'">Pixel</ShaderType>
|
||||
<ShaderType Condition="'$(Configuration)|$(Platform)'=='Release|x64'">Pixel</ShaderType>
|
||||
</FxCompile>
|
||||
<FxCompile Include="SimpleVertexPBR.hlsl">
|
||||
<ShaderType Condition="'$(Configuration)|$(Platform)'=='Debug|x64'">Vertex</ShaderType>
|
||||
<ShaderType Condition="'$(Configuration)|$(Platform)'=='Debug|Win32'">Vertex</ShaderType>
|
||||
<ShaderType Condition="'$(Configuration)|$(Platform)'=='Release|Win32'">Vertex</ShaderType>
|
||||
<ShaderType Condition="'$(Configuration)|$(Platform)'=='Release|x64'">Vertex</ShaderType>
|
||||
</FxCompile>
|
||||
<FxCompile Include="SkyboxPixelShader.hlsl">
|
||||
<ShaderType Condition="'$(Configuration)|$(Platform)'=='Debug|x64'">Pixel</ShaderType>
|
||||
<ShaderType Condition="'$(Configuration)|$(Platform)'=='Debug|Win32'">Pixel</ShaderType>
|
||||
|
|
@ -321,7 +333,9 @@
|
|||
<ItemGroup>
|
||||
<None Include="Helpers.hlsli" />
|
||||
<None Include="Defines.hlsli" />
|
||||
<None Include="HelpersPBR.hlsli" />
|
||||
<None Include="Lights.hlsli" />
|
||||
<None Include="LightsPBR.hlsli" />
|
||||
<None Include="packages.config" />
|
||||
<None Include="SkyboxDefines.hlsli" />
|
||||
<None Include="ThirdPartyFunctions.hlsli" />
|
||||
|
|
|
|||
|
|
@ -133,6 +133,12 @@
|
|||
<FxCompile Include="SkyboxVertexShader.hlsl">
|
||||
<Filter>Shaders</Filter>
|
||||
</FxCompile>
|
||||
<FxCompile Include="SimplePixelPBR.hlsl">
|
||||
<Filter>Shaders</Filter>
|
||||
</FxCompile>
|
||||
<FxCompile Include="SimpleVertexPBR.hlsl">
|
||||
<Filter>Shaders</Filter>
|
||||
</FxCompile>
|
||||
</ItemGroup>
|
||||
<ItemGroup>
|
||||
<CopyFileToFolders Include="Assets\Models\cube.obj">
|
||||
|
|
@ -381,5 +387,11 @@
|
|||
<None Include="SkyboxDefines.hlsli">
|
||||
<Filter>Shaders</Filter>
|
||||
</None>
|
||||
<None Include="HelpersPBR.hlsli">
|
||||
<Filter>Shaders</Filter>
|
||||
</None>
|
||||
<None Include="LightsPBR.hlsli">
|
||||
<Filter>Shaders</Filter>
|
||||
</None>
|
||||
</ItemGroup>
|
||||
</Project>
|
||||
|
|
@ -4,6 +4,12 @@
|
|||
// from environment map demo
|
||||
static const float F0_NON_METAL = 0.04f;
|
||||
|
||||
// Minimum roughness for when spec distribution function denominator goes to zero
|
||||
static const float MIN_ROUGHNESS = 0.0000001f; // 6 zeros after decimal
|
||||
|
||||
// Handy to have this as a constant
|
||||
static const float PI = 3.14159265359f;
|
||||
|
||||
// gets view vector, needed once per shader
|
||||
float3 getView(float3 cameraPosition, float3 pixelWorldPosition)
|
||||
{
|
||||
|
|
|
|||
104
HelpersPBR.hlsli
Normal file
104
HelpersPBR.hlsli
Normal file
|
|
@ -0,0 +1,104 @@
|
|||
#ifndef __SHADER_HELPERS_PBR__
|
||||
#define __SHADER_HELPERS_PBR__
|
||||
|
||||
// Lambert diffuse BRDF - Same as the basic lighting diffuse calculation!
|
||||
// - NOTE: this function assumes the vectors are already NORMALIZED!
|
||||
float DiffusePBR(float3 normal, float3 dirToLight)
|
||||
{
|
||||
return saturate(dot(normal, dirToLight));
|
||||
}
|
||||
|
||||
// Calculates diffuse amount based on energy conservation
|
||||
//
|
||||
// diffuse - Diffuse amount
|
||||
// specular - Specular color (including light color)
|
||||
// metalness - surface metalness amount
|
||||
//
|
||||
// Metals should have an albedo of (0,0,0)...mostly
|
||||
// See slide 65: http://blog.selfshadow.com/publications/s2014-shading-course/hoffman/s2014_pbs_physics_math_slides.pdf
|
||||
float3 DiffuseEnergyConserve(float3 diffuse, float3 specular, float metalness)
|
||||
{
|
||||
return diffuse * ((1 - saturate(specular)) * (1 - metalness));
|
||||
}
|
||||
|
||||
// GGX (Trowbridge-Reitz)
|
||||
//
|
||||
// a - Roughness
|
||||
// h - Half vector
|
||||
// n - Normal
|
||||
//
|
||||
// D(h, n) = a^2 / pi * ((n dot h)^2 * (a^2 - 1) + 1)^2
|
||||
float SpecDistribution(float3 n, float3 h, float roughness)
|
||||
{
|
||||
// Pre-calculations
|
||||
float NdotH = saturate(dot(n, h));
|
||||
float NdotH2 = NdotH * NdotH;
|
||||
float a = roughness * roughness;
|
||||
float a2 = max(a * a, MIN_ROUGHNESS); // Applied after remap!
|
||||
|
||||
// ((n dot h)^2 * (a^2 - 1) + 1)
|
||||
float denomToSquare = NdotH2 * (a2 - 1) + 1;
|
||||
// Can go to zero if roughness is 0 and NdotH is 1; MIN_ROUGHNESS helps here
|
||||
|
||||
// Final value
|
||||
return a2 / (PI * denomToSquare * denomToSquare);
|
||||
}
|
||||
|
||||
// Fresnel term - Schlick approx.
|
||||
//
|
||||
// v - View vector
|
||||
// h - Half vector
|
||||
// f0 - Value when l = n (full specular color)
|
||||
//
|
||||
// F(v,h,f0) = f0 + (1-f0)(1 - (v dot h))^5
|
||||
float3 Fresnel(float3 v, float3 h, float3 f0)
|
||||
{
|
||||
// Pre-calculations
|
||||
float VdotH = saturate(dot(v, h));
|
||||
|
||||
// Final value
|
||||
return f0 + (1 - f0) * pow(1 - VdotH, 5);
|
||||
}
|
||||
|
||||
// Geometric Shadowing - Schlick-GGX (based on Schlick-Beckmann)
|
||||
// - k is remapped to a / 2, roughness remapped to (r+1)/2
|
||||
//
|
||||
// n - Normal
|
||||
// v - View vector
|
||||
//
|
||||
// G(l,v)
|
||||
float GeometricShadowing(float3 n, float3 v, float roughness)
|
||||
{
|
||||
// End result of remapping:
|
||||
float k = pow(roughness + 1, 2) / 8.0f;
|
||||
float NdotV = saturate(dot(n, v));
|
||||
|
||||
// Final value
|
||||
return NdotV / (NdotV * (1 - k) + k);
|
||||
}
|
||||
|
||||
// Microfacet BRDF (Specular)
|
||||
//
|
||||
// f(l,v) = D(h)F(v,h)G(l,v,h) / 4(n dot l)(n dot v)
|
||||
// - part of the denominator are canceled out by numerator (see below)
|
||||
//
|
||||
// D() - Spec Dist - Trowbridge-Reitz (GGX)
|
||||
// F() - Fresnel - Schlick approx
|
||||
// G() - Geometric Shadowing - Schlick-GGX
|
||||
float3 MicrofacetBRDF(float3 n, float3 l, float3 v, float roughness, float3 specColor)
|
||||
{
|
||||
// Other vectors
|
||||
float3 h = normalize(v + l);
|
||||
|
||||
// Grab various functions
|
||||
float D = SpecDistribution(n, h, roughness);
|
||||
float3 F = Fresnel(v, h, specColor);
|
||||
float G = GeometricShadowing(n, v, roughness) * GeometricShadowing(n, l, roughness);
|
||||
|
||||
// Final formula
|
||||
// Denominator dot products partially canceled by G()!
|
||||
// See page 16: http://blog.selfshadow.com/publications/s2012-shading-course/hoffman/s2012_pbs_physics_math_notes.pdf
|
||||
return (D * F * G) / (4 * max(dot(n, v), dot(n, l)));
|
||||
}
|
||||
|
||||
#endif
|
||||
29
LightsPBR.hlsli
Normal file
29
LightsPBR.hlsli
Normal file
|
|
@ -0,0 +1,29 @@
|
|||
#ifndef __SHADER_LIGHTS_PBR__
|
||||
#define __SHADER_LIGHTS_PBR__
|
||||
|
||||
// Gets the RGB value of a pixel with a directional light
|
||||
float3 directionalLightPBR(Light light, float3 normal, float3 view, float roughness, float metalness, float3 surfaceColor, float3 specularColor)
|
||||
{
|
||||
float3 lightDirection = normalize(light.Direction);
|
||||
float diffuse = DiffusePBR(normal, -lightDirection);
|
||||
float3 specular = MicrofacetBRDF(normal, lightDirection, view, roughness, specularColor);
|
||||
|
||||
float3 balancedDiff = DiffuseEnergyConserve(diffuse, specular, metalness);
|
||||
|
||||
return (balancedDiff * surfaceColor + specular) * light.Intensity * light.Color;
|
||||
}
|
||||
|
||||
// Gets the RGB value of a pixel with a point light
|
||||
float3 pointLightPBR(Light light, float3 normal, float3 view, float roughness, float metalness, float3 surfaceColor, float3 specularColor, float3 worldPosition)
|
||||
{
|
||||
float3 lightDirection = normalize(light.Position - worldPosition);
|
||||
float attenuation = getAttenuation(light.Position, worldPosition, light.Range);
|
||||
float diffuse = DiffusePBR(normal, lightDirection);
|
||||
float3 specular = MicrofacetBRDF(normal, lightDirection, view, roughness, specularColor);
|
||||
|
||||
float3 balancedDiff = DiffuseEnergyConserve(diffuse, specular, metalness);
|
||||
|
||||
return (balancedDiff * surfaceColor + specular) * attenuation * light.Intensity * light.Color;
|
||||
}
|
||||
|
||||
#endif
|
||||
63
SimplePixelPBR.hlsl
Normal file
63
SimplePixelPBR.hlsl
Normal file
|
|
@ -0,0 +1,63 @@
|
|||
#include "Defines.hlsli"
|
||||
#include "Helpers.hlsli"
|
||||
#include "HelpersPBR.hlsli"
|
||||
#include "Lights.hlsli"
|
||||
#include "LightsPBR.hlsli"
|
||||
|
||||
#define MAX_LIGHTS 128
|
||||
|
||||
cbuffer ExternalData : register(b0)
|
||||
{
|
||||
float2 offset;
|
||||
float2 scale;
|
||||
|
||||
float3 cameraPosition;
|
||||
float lightCount;
|
||||
|
||||
Light lights[MAX_LIGHTS];
|
||||
}
|
||||
|
||||
Texture2D Albedo : register(t0);
|
||||
Texture2D Normal : register(t1);
|
||||
Texture2D Roughness : register(t2);
|
||||
Texture2D Metalness : register(t3);
|
||||
TextureCube Reflection : register(t4);
|
||||
SamplerState Sampler : register(s0);
|
||||
|
||||
float4 main(VertexToPixel input) : SV_TARGET
|
||||
{
|
||||
input.normal = normalize(input.normal);
|
||||
input.tangent = normalize(input.tangent);
|
||||
|
||||
float3 view = normalize(cameraPosition - input.worldPosition);
|
||||
|
||||
float4 albedo = pow(Albedo.Sample(Sampler, input.uv), 2.2f);
|
||||
|
||||
float3 N = Normal.Sample(Sampler, input.uv).rgb * 2 - 1;
|
||||
float3 T = normalize(input.tangent - input.normal * dot(input.tangent, input.normal));
|
||||
float3 B = cross(T, input.normal);
|
||||
float3x3 TBN = float3x3(T, B, input.normal);
|
||||
input.normal = mul(N, TBN);
|
||||
|
||||
float roughness = Roughness.Sample(Sampler, input.uv).r;
|
||||
float metalness = Metalness.Sample(Sampler, input.uv).r;
|
||||
float3 specular = lerp(F0_NON_METAL.rrr, albedo.rgb, metalness);
|
||||
|
||||
float3 light = albedo;
|
||||
for (int i = 0; i < lightCount; i++)
|
||||
{
|
||||
switch (lights[i].Type)
|
||||
{
|
||||
case LIGHT_TYPE_DIRECTIONAL:
|
||||
light += directionalLightPBR(lights[i], input.normal, view, roughness, metalness, albedo, specular);
|
||||
break;
|
||||
case LIGHT_TYPE_POINT:
|
||||
light += pointLightPBR(lights[i], input.normal, view, roughness, metalness, albedo, specular, input.worldPosition);
|
||||
break;
|
||||
}
|
||||
}
|
||||
|
||||
float3 final = light;
|
||||
|
||||
return float4(pow(final, 1.0f / 2.2f), albedo.a);
|
||||
}
|
||||
24
SimpleVertexPBR.hlsl
Normal file
24
SimpleVertexPBR.hlsl
Normal file
|
|
@ -0,0 +1,24 @@
|
|||
#include "Defines.hlsli"
|
||||
|
||||
cbuffer ExternalData : register(b0)
|
||||
{
|
||||
matrix world;
|
||||
matrix worldInvTranspose;
|
||||
matrix view;
|
||||
matrix projection;
|
||||
}
|
||||
|
||||
VertexToPixel main(VertexShaderInput input)
|
||||
{
|
||||
VertexToPixel output;
|
||||
|
||||
matrix worldViewProjection = mul(projection, mul(view, world));
|
||||
output.screenPosition = mul(worldViewProjection, float4(input.localPosition, 1.0f));
|
||||
|
||||
output.uv = input.uv;
|
||||
output.normal = normalize(mul((float3x3)worldInvTranspose, input.normal));
|
||||
output.tangent = normalize(mul((float3x3)worldInvTranspose, input.tangent));
|
||||
output.worldPosition = mul(world, float4(input.localPosition, 1)).xyz;
|
||||
|
||||
return output;
|
||||
}
|
||||
Reference in a new issue